<?LassoScript

	//
	// -SQL Permissions
	//
	// Fletcher Sandbeck
	// fletcher@blueworld.com
	// Blue World Communications
	// 9/19/2002
	//
	// Added on 10/9/2002 by Bram Verniest bram@pregoweb.com
	// I added the '-op=eq' part in the query
	// this was needed for table_id's bigger than 99 (starting with 1 thus)
	//
	// This format file add a default permission entry so all permissions
	// will work the same as they did in Lasso Professional 5.
	//
	// Installation - Copy this file into LassoStartup and restart Lasso
	// Service.  This will ensure that this fix is run each time Lasso
	// Service is started up.
	//

	auth_admin;  // Checks for administrator privileges

	{
		local: 'refresh' = false;

		// Searches for the AnyUser record for All Tables in the tables map.
		inline: -search, 
				-database='lasso_internal', 
				-table='security_group_table_map', 
				-keyfield='id',
				-op='eq',
				'id_group'='1', 
				-op='eq',
				'id_table'='1';

				if: (found_count) == 0;

						local: 'refresh' = true;

						// If no record is found then a new one is created with SQL
						// permission allowed.
						inline: -add, 
								-database=(database_name), 
								-table=(table_name), 
								-keyfield=(keyfield_name), 
								'id_group'='1', 
								'id_table'='1', 
								'allow'='Q', 
								'deny'='';
						/inline;
				else;
						records;

								// Modify the allow field by adding SQL permission.
								local: 'allow' = (field: 'allow');
								if: !(#allow >> 'Q');
										local: 'refresh' = true;
										#allow += ',Q';
										#allow->(removeleading: ',');
										#allow->(removetrailing: ',');
										#allow->(replace: ',,', ',');
								/if;

								// Modify the deny field by removing a block on SQL
								// statements.
								local: 'deny' = (field: 'deny');
								if: (#deny >> 'Q');
										local: 'refresh' = true;
										#deny -= 'Q';
										#deny->(removeleading: ',');
										#deny->(removetrailing: ',');
										#deny->(replace: ',,', ',');
								/if;

								// If either allow or deny was modified then update the
								// record.
								if: #refresh == true;
										inline: -update, 
												-database=(database_name), 
												-table=(table_name), 
												-keyfield=(keyfield_name), 
												-keyvalue=(keyfield_value), 
												'allow'=#allow, 
												'deny'=#deny;
										/inline;
								/if;

						/records;

				/if;

		/inline;

		// If a modification was made then refresh Lasso's security caches.
		if: #refresh == true;
				_security_flushcaches;
		/if;

	}->run;

?>